Guide de Neuro des macros pour WoW 2.0

Source.

(Note de l'auteur: WoW 2.0 est toujours en Beta, et jusque là, ces options peuvent changer à n'importe quel moment)

Dans WoW 2.0, les macros et addons vont changer de façon drastique. Récemment, Slouken a annoncé de nouveaux ajouts, pour le moins excitants, aux fonctionnalités des macros dans WoW 2.0, un groupe d'options conditionnels pour les commandes /cast, /use, /target, /focus, /assist, /stopmacro, /cancelaura, /userandom, /castrandom, et /castsequence. Ce poste a pour but d'être un guide du "Comment ça marche", afin de les utiliser.

NOTE: Bien que la plupart des exemples fournis sont rédigés en utilisant '/cast', ces options sont disponibles sur toutes les commandes listées un peu plus haut.

Comprenez que la plupart des macros actuelles seront obselètes à la 2.0. Tout ce qui concerne l'utilisation de CastSpellByName() ou TargetUnit() ne sera plus possible en combat. De plus, la plupart des macros "défiant la logique" ne fonctionneront plus non plus. Cependant, vous pouvez désormais répliquer les fonctionnalités de nombreuses macros connues avec ces nouvelles options de macros.

Actuellement, utiliser '/cast' est très simple. Le format de la commande est '/cast <nom du sort>' (lequel lancera le rang le plus haut du sort que vous possédez), ou '/cast <nom du sort>(Rang <#>)'. Quelques exemples:

/cast Greater Heal
/cast Arcane Intellect(Rank 3)

Dans le nouveau système, ce format fonctionne toujours de la même façon, cependant vous pouvez maintenant ajouter des options pour donner plus de flexibilité à votre '/cast'. Le nouveau format de la commande pour '/cast' est: '/cast [<1er groupe d'options>] <nom du premier sort>; [<2nd groupe d'options>] <nom du second sort>; [<3e groupe d'options>] <nom du troisième sort>; ...'

La façon dont fonctionne la macro est la suivante: Le premier groupe d'options est vérifié. S'il est vrai, alors le premier sort est lancé. S'il est faux, le groupe d'options suivant est évalué, et si vrai, le sort suivant est lancé, et ainsi de suite. Cependant, vous devez garder à l'esprit que seul un sort sera lancé. Dés l'instant où un groupe d'options est évalué comme vrai, le jeu lancera le sort correspondant et le déroulement de la macro se terminera à cet endroit.

Les options actuellement accessibles aux joueurs sont :
# help - évaluée à 'vrai' si la cible est amicale

# harm - évaluée à 'vrai' si la cible est hostile

# combat - évaluée à 'vrai' si vous êtes en combat

# stance ou stance:# - évaluée à 'vrai' si vous êtes dans une position, ou une position particulière (voir plus bas)

# stealth - évaluée à 'vrai' si vous êtes camouflés.

# modifier ou modifier:shift|ctrl|alt - évaluée à 'vrai' si la touche de clavier sélectionnée est enfoncée quand la commande est exécutée.

# equipped:<objet> - évaluée à 'vrai' si l'objet est équipé. L'objet peut être dans n'importe quel place valide de votre inventaire, objet de classe ou de sous-classe.

# target=<unité> - option spéciale. Cela change la cible de la "cible" par défaut à n'importe quel identifiant d'unité valide (voir plus bas).

# actionbar:<number> - évaluée à 'vrai' si la barre d'action actuelle est la même que l'une de celles listées.

NOUVELLES OPTIONS:
# pet:<type de pet OU nom du pet> - évaluée à 'vrai' si le pet existe. Prenez le type de pet (Hibou, Ours, Diablotin) ou le nom du pet (Fluffy, MrBigglesworth). Avec aucun modificateur (ex. juste [pet]) cela sera évalué à 'vrai' si n'importe quel animal existe.

# mounted, swimming, flying - évaluée à 'vrai' si vous êtes en monture, en train de nager ou en train de voler, respectivement.

# indoors, outdoors - évaluée à 'vrai' si vous êtes en extérieur ou en intérieur, respectivement. (J'avoue ne pas trop comprendre l'intérêt... Peut-être une erreur de compréhension de ma part dans la traduction... - NdT)

# button:<#> - évaluée à 'vrai' si le bouton sélectioné a été utilisé pour 'cliquer' sur le sort, par défaut égal à 1 (voir plus bas).

# channeling:<sort> - évaluée à vrai si vous êtes en train de lancer un des sorts listés. Si aucun sort n'est listé, cela sera évalué à vrai pour n'importe quel sort en train d'être lancé.

# exists et dead - évaluée à vrai si votre cible est morte, ou existe actuellement.

# party - évaluée à vrai si la cible est un membre de votre groupe.

# raid - évaluée à vrai si la cible est un membre de votre groupe ou votre raid.

#group - évaluée à vrai si vous êtes dans un groupe

# group:party/raid - évaluée à vrai si vous êtes dans un des types de groupe spécifiés.


Nouvelles macro commandes
-------------------------------
/castsequence - Lance un groupe de sorts prédéterminés à la suite (voir plus bas).
# show <sort> - Montre le feedback des macros pour les sorts listés.

Quelques petits trucs additionnels que vous pouvez réaliser avec les options:

Vous pouvez ajouter 'no' au début de chaque option (à l'exception de target) pour l'inverser, ex. 'nocombat' ne fonctionnera que si vous n'êtes PAS en combat.

Séparer les options avec une virgule ',' agira comme une rapport 'et'; si les deux options sont vraies, la macro s'exécutera. Séparer les options avec un slash '/' agira comme un rapport 'ou'; si l'un ou l'autre des arguments est vrai, la macro s'exécutera. Notez que cela fonctionne seulement avec les arguments contenant une option, PAS entre les options elles-mêmes (Donc, alors que [stance:1/2] est valide, [combat/help] ne l'est pas).

Sélectionner l'icône '?' dans l'éditeur de macro forcera la macro à afficher l'icône du sort actuel que la macro renvoie.

Voici quelques exemples pour vous aider :

/cast Soin supérieur
Macro très simple qui lance le sort Soin supérieur sur votre cible

/cast [help] Soin supérieur
Une option ajoutée. Le sort sera lancé SI la cible est amicale.

/cast [help] Soin supérieur; Flammes sacrées
Un second sort ajouté. Puisqu'il n'a aucune option ajoutée, il sera lancé chaque fois que la première option n'est pas vrai.

/cast [help, combat] Soin rapide; [help, nocombat] Soin supérieur; Flammes sacrées
Cette macro lancera un Soin rapide sur une cible amicale si vous (et non votre cible) êtes en combat. Si vous n'êtes pas en combat et que la cible est amicale, il lancera Soin supérieur. Dans tout autre cas, il lancera Flammes sacrées.

/cast [help] Soin supérieur; [harm, combat] Flammes sacrées; [harm, nocombat] Contrôle mental
Cela lancera Soin supérieur sur une cible alliée, ou Flammes sacrées sur une cible hostile si vous êtes en combat, ou Contrôle mental si vous n'êtes pas en combat.

/cast [stealth] Embuscade; Attaque sournoise
Cela lancera Embuscade si vous êtes camouflés, Attaque sournoise si ça n'est pas le cas.

/cast [nostealth] Attaque sournoise; Embuscade
Exactement la même chose qu'au dessus, mais écrit d'une façon différente.

/cast [actionbar:1] Soin supérieur; [actionbar:2] Flammes sacrées
Lancera Soin supérieur si la barre d'action actuelle est #1, Flammes sacrées si la barre d'action actuelle est #2, rien si ce sont les barres d'action #3 ou plus qui sont sélectionnées.

/cast [harm] Métamorphose
/stopmacro [noharm]
/p Je sheep %t ! TOUCHE PAS AU GRISBI, SALOPE !
Cette macro lancera Métamorphose si la cible est hostile, puis arrête la macro si la cible n'est PAS hostile (ex. si la Métamorphose n'est pas partie). Puis cela dit au groupe que cette cible a été transformée. Notez que grâce à la commande '/stopmacro', si la cible n'a pas été transformée, le groupe ne recevra pas de message (coupant court au spam inutile).

/cast [pet] Call; Revive Pet
(Bon, à partir de là, je ne traduirai plus forcément les termes. Je ne les connais pas tous, et vous êtes censé connaître vous :p - NdT)
Cette macro appelera votre pet si vous n'en avez pas, sinon il tentera de le ressuciter.

/cast [pet:owl] Dive; [pet:cat] Dash; [pet] Growl
Cette macro lancer Dive si vous avez un hibou, Dash si vous avez un chat, ou Growl si vous avez n'importe quoi d'autre.

/cast [pet:Voidwalker] Sacrifice; [pet:succubus] Seduction
Lancera Sacrifice si vous avez un marcheur éthéré de sorti, Séduction si c'est une succube.

/use [nomounted,outdoors] Black War Steed Bridle
Cela tentera d'invoquer votre monture si vous êtes dehors et pas encore sur une monture.

/cast [target=pet,dead] Revive Pet; [nopet] Call Pet; Mend Pet
Cela ressucitera votre animal s'il est mort, appelera votre animal si vous ne l'avez pas sorti ou le nourrira.

/cast [groupe:party] Arcane Brilliance; Arcane Intellect
Lancera AB si vous êtes dans un groupe, ou AI sinon.

/cast [raid] Blessing of Wisdom
Lancera Blessing of Wisdom si votre cible est dans le même raid que vous.

--------------
Les Positions
--------------

Les Positions fonctionnent de la même façon. Si aucun numéro de position n'est donné, alors il évaluera à 'vrai' si le player est dans une position, quelqu'elle soit. (Notez que pour le guerrier, vous êtes TOUJOURS sous une position ou une autre). Si un numéro est donné, cela vérifiera si c'est la forme actuellement activée.

Chaque classe a différents numéros pour ces positions. Voici une liste des positions et leurs numéros:

Guerrier:
# stance:1 - Battle
# stance:2 - Defensive
# stance:3 - Berserker

Prêtre
# stance:1 - Forme d'ombre

Druide
# stance:1 - Ours
# stance:2 - Aquatique
# stance:3 - Chat
# stance:4 - Voyage
# stance:5 - Arbre/Moonkin (?)

Voleur
# stance:1 - Camouflé

Les auras des Paladins ne sont plus considérés comme des Positions par le système de Macro.

Gardez en tête que s'il vous manque une position (comme un guerrier qui n'aurait jamais fait la quête pour avoir la position Defensive) alors votre numéro de Position descendra d'un cran, ex. Position Berserker serait alors stance:2.

Quelques exemples de positions:
/cast [nostance] Bear Form
Si vous n'êtes sous aucune forme, vous passerez en ours.

/cast [stance:1] Overpower; [stance:2] Sunder Armor; [stance:3] Whirlwind
Lancera Overpower en Position Battle, Sunder Armor en Defensive, et Whirlwind en position Berserker.

/cast [stance:1] Growl; [stance:2] Claw
Lancera Growl en forme d'Ours, ou Claw en forme de chat.

/cast [nostance:3] Cat Form
Vous transformera en chat si vous ne l'êtes pas déjà. Si vous l'êtes déjà, cela ne vous sortira PAS de la forme du chat.

L'option [equipped] fonctionne aussi de la même façon, mais cela demande un peu plus de manipulation. L'arguement peut-être un emplacement de l'inventaire (voir plus bas), un type d'objet ou un sous-type d'objet. Pour une liste des types d'objets et sous-types d'objets, allez voir ici : http://www.wowwiki.com/ItemType

Une liste des emplacements d'inventaire :
Two-Hand
Bag
Shirt
Chest
Back
Feet
Finger
Hands
Head
Held In Off-hand
Legs
Neck
Ranged
Chest
Off Hand
Shoulder
Tabard
Thrown (emplacement d'objets lancés comme les dagues de lancer)
Trinket
Waist
One-Hand
Main Hand
Off Hand
Wrist

(La question est: peut-on utiliser les termes anglais ou va-t-il falloir les traduire... Je crois qu'il va falloir les traduire comme on doit déjà le faire pour les compétences. Donc à vos dicos ! - NdT)

Quelques exemples de [equipped] :

/cast [equipped:Two-Handed Swords] Mortal Strike; Heroïc Strike
Cela lancera Frappe Mortelle si vous utilisez une epée deux mains, sinon Frappe héroïque.

/cast [equipped:Two-Handed Swords/Two-Handed Maces/Two-Handed Axes/Polearms] Mortal Strike
Cela utilise le modificateur '/' pour obtenir une condition 'ou'. Cette macro lancer Frappe Mortelle si l'UN de ces types d'arme est équipé.

/cast [equipped:Shields] Shield Bash
Cela lancera Shiekd Bash si vous avez un bouclier d'équipé.

/cast [equipped:Shields, equipped:Daggers] Shield Slam
Cela lancera Shield slam, seulement si vous avez une dague ET un bouclier d'équipés.

/cast [noequipped:Shields, equipped:Off Hand] Rampage
Cela lancera Rampage si vous n'avez PAS équipé de bouclier, ET que vous avez quelque chose dans votre main gauche. En théorie, cette macro ne fonctionne que si vous êtes en Ambi.

L'option [button:<x>] fonctionne de la même façon que le modificateur "button". Normalement, si vous cliquez gauche sur un bouton, cela lancera le sort, quelqu'il soit, dans notre cas une macro. Cependant, si vous activez l'option "button", vous pouvez modifier le comportement d'une macro particulière.

Le bouton par défaut est 1, le bouton gauche de la souris. Notez que quand vous activez une macro via une touche de raccourci, cela est traité comme un clic du bouton gauche de la souris. Les correspondances des boutons sont :
1 ou LeftButton (Bouton Gauche)
2 ou RightButton (Bouton Droit)
3 ou MiddleButton (Bouton du Milieu)
4 ou Button4 (Bouton 4)
5 ou Button5 (Bouton 5)
... Ou n'importe lequel des boutons reconfiguré par les formes d'entêtes sécurisés (ou un truc dans le genre, c'est pas important de toute façon :p - NdT).

/cast [button:2,target=player] Flash Heal; [help] Flash Heal
Cette macro lancera Flash heal sur une cible allié, OU sur vous, si vous cliquez dessus avec le bouton droit de la souris


[target=unit] est une option spéciale. Au lieu d'évaluer si c'est 'vrai' ou 'faux', elle changera la cible pour le sort suivant ET pour les autres options. "Unit" peut être n'importe quelle unité valide, ex. "player", "target", "targettarget", "party1", "party1target", etc etc. Pour plus de types d'unités, allez ici: http://www.wowwiki.com/UnitId

Gardez en tête que chaque sort a "target" comme cible par défaut. Donc, par exemple :

/cast [help] Greater Heal

est la même chose que

/cast [target=target, help] Greater Heal

A moins que vous ajoutiez un [target=unit], cela affectera votre cible courante par défaut.

Quelques exemples possibles de [target=unit] :

/cast [target=player] Flash Heal
Cela lancera toujours Flash Heal sur vous-même. Notez que votre cible courante ne changera pas.

/cast [help] Flash Heal; [target=targettarget] Flash Heal
Cela lancera Flash heal sur votre cible si celle-ci est amicale, OU cela lancera Flash Heal sur la cible de votre cible.

/cast [help, combat] Flash Heal; [help, nocombat] Greater Heal; [target=targettarget, help, combat] Flash Heal; [target=player] Greater Heal
Cette macro fera soit 1) Flash Heal si la cible est amicale et que vous êtes en combat, 2) Soins supérieurs si la cible est amicale et que vous n'êtes PAS en combat, 3) Flash Heal sur la cible de votre cible si vous êtes en combat et que cette cible est amicale, ou si aucune de ces conditions n'est vérifiée, cela lancera Great Heal sur vous-même.

Si vous utilisez l'identifiant d'unité "none", cela agira comme si vous n'aviez AUCUNE cible. Par exemple:

/cast [target=none] Dispel Magic
Cela lancera Dispel Magic puis demandera une cible, sans tenir compte de la cible que vous avez actuellement selectionnée.

Nouvelle commande : /castsequence
----------------------------------

Il y a une nouvelle commande dans WoW 2.0, appelée /castsequence. Cela vous permet de mettre en place une série de sorts à lancer l'un après l'autre, pour chaque clic supplémentaire sur la macro. Le format est :

/castsequence [<options>] reset=<#>/target/combat/alt/shift/ctrl <spell1>, <spell2>, <spell3>

"Hein ? Qu'est-ce que tu as dit ?"

Cela crée une liste de sorts, et la première fois que vous cliquez sur la macro, elle lancera le premier sort de la liste. La fois suivante, ce sera le second sort qui partira, et ainsi de suite. Lorsque l'on atteind la fin, on revient au début.

"Je ne te suis toujours pas."

Ok, disons que tu es un mage. Quelques fois, tu as besoin de faire Frost Nova puis de te téléporter rapidement au loin. Tu ne peux pas faire les deux en même temps, dont tu crées une séquence pour le faire !

/castsequence Frost Nova, Blink

Et voilà le travail. La première fois que tu cliques, tu lances Frost Nova, puis tu cliques encore et tu te téléportes.

"Eh, Je rigolais un peu à propos de ce truc de combat. Ok, alors qu'est-ce qui arrive si j'utilise Frost Nova, et décide de ne pas me téléporter ? La prochaine fois que je veux utiliser Frost Nova, cela ira sur le "Blink" enregistré ?"

Ca n'est pas un problème. Nous utiliseront le nouveau "reset" de paramètres. Puisque Frost Nova a un cooldown de 24 secondes normalement, nous configurerons la séquence pour qu'elle "reset" après 24 secondes de non-utilisation.

/castsequence reset=24 Frost Nova, Blink

La première fois que tu cliques sur la macro, cela lancera Frost Nova. Si tu décides de ne pas te téléporter, après 24 secondes, la macro se repositionnera sur le Frost Nova. Puisque le cooldown de Frost Nova se termine au bout de 24 secondes, ce sera disponible à l'utilisation encore. Merveilleux !

"Ok, c'est génial et tout, mais moi, je suis un démo, chef."

Bien sur que tu l'es. Eh bien, en tant que démoniste, je suis sur que tu lances 3 DoTs encore et encore. Maintenant tu peux créer une séquence pour ceux là et gagner de la place.

/castsequence Corruption, Immolate, Curse of Agony

Et voilà, maintenant tu n'as plus qu'à appuyer sur ce bouton trois fois et lancer ces trois DoTs à la suite.

"Mais qu'est-ce qui se passe s'il meurt avant que j'ai fini de lancer les trois sorts ? Je suis bloqué à la fin de la séquence encore, et je ne veux pas intégrer de timer !" (Mais quel bande de chieurs ces démonistes ! ;p - NdT)

Ne t'en fais pas, nous pouvons utiliser d'autres options. Si tu indiques 'reset=target', alors chaque fois que tu changes de cible, la séquence reprendre du début. Tu peux aussi mettre 'reset=combat', et le jeu remettra à zero ta séquence chaque fois que tu passeras hors combat. Si tu utilises le modificateur '/' (tu t'en souviens, dans le début ?), tu peux combiner des options de remise à zero !

/castsequence reset=combat/target Corruption, Immolate, Curse of Agony

Voila, maintenant chaque fois que tu changes de cibles (genre, si la cible est presque morte et que tu veux commencer sur une nouvelle), ou chaque fois que tu quittes le combat (peut-être que la personne est morte avant que tu finisses de lancer tous tes DoTs), cela remettra à zero la séquence pour toi, te laissant prêt à recommencer.

"Et que faire si je veux remettre à zéro ma séquence à la main, hein ?"

Eh bien, tu peux ajouter un modificateur pour remettre à zéro, comme:

/castsequence reset=combat/target/shit Corruption, Immolate, Curse of Agony

Maintenant, si tu maintiens la touche shift enfoncé pendant que tu appuies sur ta macro, cela remettra à zero automatiquement ta séquence à son début et lancera Corruption.

"Ok, génial, je pense que j'ai saisi maintenant ! Donne moi quelques secondes pour créer mes nouvelles macros...... Et voilà !"

Excellent, je suis content d'avoir pu t'aider.

"Alors... Un petit duel ?"

Hum, non merci. Je ne duelle pas les démonistes.

"Pff, t'es naze."

(N'oubliez pas de remplacer les noms de sorts anglais par les noms français si vous avez un client WoW français ! Sinon ça ne marchera pas, c'est évident ! - NdT)

Quelques exemples de macros:

Macros générales
/use [target=player] <nom d'un bandage>
Cette macro utilisera tout le temps le bandage indiqué sur vous, sans vous faire perdre votre cible.

Macros de guerriers
Intercept/Charge : Cela fera une charge/interception, ou vous mettra dans la position correct.
/cast [nocombat,stance:1] Charge; [combat,nostance:3] Berserker Stance; [nocombat,nostance:1] Battle Stance; [combat, stance:3] Intercept

Macro de position générique: Remplacez <* Stance Ability> avec ce que vous voulez
/cast [stance:1] <Battle Stance Ability>; [stance:2] <Defensive Stance Ability>; [stance:3] <Berserker Stance Ability>

Overpower: une macro très simple pour Overpower
/cast [stance:1] Overpower; Battle Stance

Macros de mages
[i}Pyro/Fireball: Lance Pyro si vous n'êtes pas en combat (comme ouverture), Fireball sinon[/i]
/cast [nocombat] Pyroblast; Fireball

Polymorph Focus: transformera en permanence votre cible focussée
/cast [target=focus] Polymorph

Macros pour prêtres
Soins supérieurs sur la cible actuelle du boss, ou sur la cible actuelle
/cast [target=targettarget, help] Greater Heal; [help] Greater Heal

Macros pour chasseurs
Nourri/Mend animal en se basant sur le statut de combat
/cast [combat] Mend Pet; [nocombat] Feed Pet
/use [nocombat] <objet nourriture>


Remerciements
(Non, c'est pas traduit, démerdez vous ! >_< - NdT)

I'd like to take this time to give thanks to the following people:

Cogwheel, for helping collect and promote the suggestions of the UI community.

Iriel, for always helping clarify and collate information posted on the forum.

Cairenn for pushing so hard to get Mod writers into the BC Beta, and supporting them 100% with feedback and webspace.

To all the Mod Authors and Mod Websites for their wonderful and thankless work to improve the life of the other 99% of the playerbase.

And most importantly, SLOUKEN, the best dev a modding community could ever ask for. Without you, we'd be reduced to the standard interface for all eternity.

Quelques macros de voleur

Macro Descente Monture/Camouflage/CS (vous pouvez faire shift-clic sur votre monture pour afficher le nom de votre monture dans la macro)

/use [mounted] <nom monture>
/cast [nostance] Camouflage; [stance:1] Coup bas


Descente Monture/Camouflage ou Disparition/CS en un bouton !

/use [mounted] <nom monture>
/cast [nostance, combat] Disparition; [nostance] Camouflage; [stance:1] Coup bas

Si vous êtes en monture, appuyer une fois sur cette macro vous en fera descendre.
Si vous n'êtes pas déjà camouflé, et en combat, appuyer une fois sur cette macro lancera Disparition.
Si vous n'êtes pas déjà camouflé et hors combat, vous ne perdrez pas la Disparition et passerez simplement en camouflage.
Si vous êtes camouflé, vous placerez un Coup bas sur la cible.

Quand vous êtes sur une monture en BG, vous pouvez appuyer 3 fois de suite pour descendre de monture, disparaître/vous camoufler, et imédiatement placer un Coup bas.

Déluge de lames/Poussée d'adrénaline (vous pouvez ajouter Evasion à cela)

/castsequence Déluge de lames, Poussée d'adrénaline

Coup bas ou Attaque pernicieuse

/cast [stance:1] Coup bas; [nostance] Attaque pernicieuse(rang

Curseur cécité (Il faut absolument que je teste ça. Si ça fonctionne, c'est énorme !)

/cast [target=none] Blind

Cette macro devrait vous faire apparaitre un curseur de ciblage et céciter la cible que vous indiquez, sans perdre votre cible actuellement sélectionnée. Ce qui signifierait - sous réserve que ça fonctionne - plus de perte de points de combo lorsque l'on cécite une autre cible que celle que nous avons sélectionné (ex. Succube d'un démo). -- Testé. CA FONCTIONNE ! w00t ! \o/

Les macros suivantes viennent toutes de:
http://www.worldofming.com/?p=201&page=2

Sang froid + Eviscération en un bouton

/cast Sang froid
/stopcasting
/cast Eviscération(Rang 9)

SS/Riposte

/castrandom Attaque pernicieuse, Riposte

Expose l'armure ou Coup bas sans briser suriner/assomer/cécité

/equip <nom arme à distance utilisée>
/cast Exposer l'armure
/stopattack

Cheap Shot would work like this:

/equip <nom arme à distance utilisée>
/cast Coup bas
/stopattack

D'après Ming, la macro pour Exposer l'armure n'est pas totalement fiable, contrairement à celle pour le Coup bas.

Commencer l'auto-attaque, avant un coup spécial

/startattack
/cast Attaque sournoise

Remplacez Attaque sournoise par n'importe quelle attaque que vous souhaitez utiliser.

Activer un trinket, lancer evasion, AR, BF

/use 13
/castsequence Evasion, Poussée d'adrénaline, Déluge de lames

13 est l'emplacement supérieur du trinket, 14 est celui du bas. Si Evasion n'est pas dispo, les autres techniques ne se lanceront pas. Pour le moment il n'y a pas moyen de régler ça, à moins d'utiliser /castrandom et voir lancer les compétences dans un ordre aléatoire.

Préméditation suivi de Coup bas, en un seul bouton

/cast Préméditation
/stopcasting
/cast Coup bas

Mettre des poisons sur main droite et gauche (Merci à Karian qui m'a parlé de l'existence de cette macro).

/use <nom du poison>
/use [button:2] 17; 16

Voilà, avec ça, vous pourrez cliquer avec le bouton gauche de la souris sur la macro pour mettre le poison en main droite, et cliquer avec le bouton droit de la souris pour mettre en main gauche

Un bon petit guide comme il faut!

++. Glyx.

Post it

Du bon boulot, merci pour ce petit tuto Nulric

Vi merci n'Ulric, pendant que l'on pévépé toi tu bosses!!.. c'est beau

Non, ce n'est pas exactement ça. Pendant que je suis censé bosser, je m'amuse à traduire des trucs qui m'intéressent :p

Es ce que quelqu'un a une idée de comment faire pour faire une macro qui me permetrais de au début du combat de lancer des "fracassé armure" jusqu'a que la cible en ai 5 sur la gueule (appliquer par moi ou par un autre war) puis après de lancer des "Dévaster au lieu des fracasse armure?

PS magnifique poste Ulric

Lol, Theng, vu tes connaissances en prog, et le temps que tu as , je pense que tu peux te pencher sur la question non?

++. Glyx.
Ps: /kiss Theng

je suis déjà dessus mais pourquoi se faire chier si on peu avoir la réponses toutes crues

Non Thengel, cela n'est pas possible, avec les options actuelles en tout cas.

Pour la bonne et simple raison que tu ne peux pas récupérer certaines informations de ta cible avec les macros. Il est peut-être possible de programme un addon qui puisse faire cela, mais avec les macros c'est impossible.

En fait, ce qu'il faut retenir, c'est que le nouveau système de macros à pour but

1) d'éviter les macros avec un fonctionnement totalement illogique qui arrive à des combinaisons plutot abusées

2) de permettre par des macros bien construites, d'alléger considérablement les interfaces au niveau des boutons et sorts grâce à des macros et des raccourcis.

C'est d'ailleurs à cause du 2nd point que je pense que ce nouveau système profite particulièrement à tous les casteurs (je pense aux démonistes), qui doivent gérer souvent bien plus de boutons que d'autres classes. On est pas forcément des classes "2 touches" comme certains le disent bêtement, mais on est tout de même relativement léger du coté des voleurs.

PS: mon travail n'a consisté qu'à traduire de l'anglais ce qu'un autre à fait, au demeurant très bien. Il n'y a pas vraiment de mérite à cela. Mais merci, je suis content de voir que c'est apprécié.

Mise à jour des macros des voleurs.

Si vous avez des macros à proposer pour vos propres classes, mettez les ici que je les rajoutes aux autres

Code:

if ( $target == 'Ulric' )
{
  Pyro('max_rank');
}
else
{
  echo '/kiss';
}

Code:

if ( $target == 'Missmaggie' && isSpellCasting() )
{
      Cloak_of_Shadow();

      echo '/lol';
      echo '/rofl';
      echo '/taunt';
      echo '/bye';

      Vanish('max_rank');
}
elseif ( $target == 'Missmaggie' )
{
      echo '/spit';
}
else
{
    echo '/kiss';
}

Nanmého.

Bonjour a vous les Exodus !

On m a donné le lien vers votre guide de macros car je rencontre quelques soucis dans la confection de deux de mes macros .. Malheureusement je n y ai pas trouvé de solutions donc je me permet de poster en esperant que cela ne vous derange pas trop ...

j utlise cette macro pour le moment (sur Patwerk)

/use Charme de héros zandalarien
/stopcasting
/cast Focalisation améliorée
/stopcasting
/cast [help] Soins supérieurs(Rang 2)

hors le cd du trinket et de foca etant différents cette macro se desynchronise :s (cd de foca = 3min; cd du trinket = 2min30sec)
en gros je voudrais savoir comment appliquer un reset de 3 min a l utilisation du trinket afin qu il ne se lance pas tant que la foca n est pas up .


deuxieme probleme

j utilise ces deux macros

/castsequence [target=mouseover,exists] reset=4 Mot de pouvoir : Bouclier(Rang 10), Rénovation(Rang 10)
et
/cast [target=targettarget] reset=18 Mot de l'ombre : Douleur(Rang

et je voudrais les rassembler en une seule .. hors il semble que les fonction mouseover et targettarget ne soient pas compatibles car toutes mes tentatives sont des echecs .. ca lance le bouclier et la renew mais pas de dot sur la cible de ma cible :s

voila voila si l un de vous arrive a trouver la solution je le /lick
Merci d avance et encore désolé de venir polluer votre fofo mais je commence craquer apres plusieurs jours d epluchage de forums divers et variés ^^

Salut Kyu.
Bon, je suis loin moi-même de maîtriser les macros à la perfection, donc il ne faudra pas prendre pour argent comptant ce que je vais te dire. Cependant n'oublie pas que même si les possibilités des macros sont toujours énormes, la portée de leur action a été particulièrement réduite depuis le dernier patch.

Pour ton premier problème, j'ai bien peur qu'il n'y ait aucune solution à part attendre que tes cooldowns soient tous terminés pour relancer la macro. En effet, la forme que tu utilises permet justement de pouvoir lancer le "sort final" même si les cooldowns de tes autres bijoux/techniques ne sont pas finis, offrant ainsi une sauvegarde de place.

Peut-être avec /castsequence qui permet d'ajouter le reset sur le temps, mais si j'ai bien compris le fonctionnement de cette commande, je doute qu'elle règle ton probème aussi. Tout au plus, tu ne pourras pas du tout utiliser cette macro tant que le cooldown du premier trinket ne sera pas up, en admettant qu'elle permette l'utilisation des trinkets.

Pour le deuxième problème, en effet, mouseover et targettarget ne sont pas compatible. Mouseover va lancer le sort sur la personne actuellement sous le curseur de ta souris (assez utile pour le décurse en passant), mais en faisant cela, tu ne cibles pas réellement la personne (elle n'apparait pas dans ton interface comme tel, puisque tu ne la sélectionnes pas en cliquant dessus), pour le jeu, elle n'est donc pas considérée comme ta cible, et dés lors, pour placer ton DoT, c'est comme si tu ciblais la cible... du vide. Autant dire que tu ne peux pas grand chose contre le vide :p

Il va donc falloir que tu trouves une autre solution si tu souhaites toujours faire la même chose. Mais je ne pense pas qu'il y ait une solution réellement satisfaisante à moins de faire un bricolage assez moche.

Les macros c'est magique mais pas miraculeux x)

En espérant avoir été d'une quelconque aide. Bonne continuation à toi et peut-être à bientôt dans le jeu =)

Salut Ulric

Deja merci d'avoir répondu si rapidement a mon post ^^
Ensuite tu confirmes mes craintes a savoir qu il n y a pas de solution tout simplement ^^
pour la premiere macro elle a l avantage de tout lancer en un seul click contrairement a la meme en /castsequence ou il faudra 3 click pour la finaliser ... hors meme si il est possible de mettre un reset sur une /castsequence cela n est pas rentable au niveau du temps passé a spammer la maccro sur un combat comme celui de patchwerk..
je vais donc devoir utiliser la macro que j ai actuellement lorsque les cd seront up et simplement utiliser le sort en attendant que les cd se rechargent ..

Pour la deuxieme c est fort dommage car un couplage de ces deux macros optimiserait le dps trop peu utilisé du pretre mais bon je vais continuer avec le combo des deux macros dissociée c est mieux que rien

encore merci pour ton attention et au plaisir de se croiser au bg qui sait

MMM Ulric, dans ton post sur "castsequence"; tu indiques

/castsequence reset=24 Frost Nova, Blink
le reset 24 etant le CD de 24s.
N'y a t'il pas moyen d'utiliser cette commande pour Kyu?

Et merci Bcp pour ce guide. J'ai pas tt saisi encore mais cha va viendre!

Non, pas du tout. Le reset permet seulement de remettre la séquence au début lorsque, comme c'est indiqué dans l'exemple, tu n'as pas fini la séquence et que le cooldown de ta première technique est fini.

Si tu fais une nova mais que tu n'utilises pas le blink, la prochaine fois que tu cliqueras tu lanceras le sort blink parce qu'il est enregistré en mémoire dans la séquence.

Or, une fois le cooldown de nova terminé, j'assume que tu aimerais pouvoir relancer ta séquence du début, et ne pas te retrouver à te téléporter sans faire de nova. Le reset sert à cela.

ok merci!

En tous les cas ces cast sequence sont pas mal du tout parceq ue par defaut les commandes sont "intellige,ntes", au moins dans le cas de druide
genre si tu as /castsequence Récupération, Prompte guérison, récupération, si tu as deja lancé une recup sur ta cible, en manuel "hors macro", il passe direct a la prompte guérison.